Spreadsheet (1)

La siguiente guía detalla el proceso para validar el RUT en spreadsheet de Google sin el uso de scripts ni macros como Excel. Esto implica que únicamente mediante fórmulas de la hoja de cálculo, podemos determinar la validez de un RUT ingresado o incluso obtener el dígito verificador correspondiente.

Pasos para validar RUT

Para Validar RUT en Spreadsheet, inicialmente, crearemos dos hojas en el spreadsheet de Google: una destinada al ingreso del RUT y a la obtención de resultados, y la segunda enfocada en los cálculos necesarios. En este caso la primera se llama Verificar RUT y la segunda Calculos.

Validar RUT en Spreadsheet

Como se puede observar en la primera hoja destinada a la verificación de RUT, encontramos dos celdas. La primera está diseñada para introducir el RUT que se desea verificar, mientras que la segunda proporciona el resultado indicando si el RUT es válido o no, además de mostrar el dígito verificador correspondiente.

Los cálculos

En la hoja de cálculos, el primer paso consistirá en extraer el RUT sin el Dígito Verificador (DV). Para lograrlo, aplicaremos la siguiente fórmula. Esto utilizando la columna C y la primera formula la pondré en la fila 2.

=LEFT('Verificar RUT'!C4;IF(LEN('Verificar RUT'!C4)=9;7;8))

Para abordar esta explicación, es necesario iniciar con la fórmula contenida dentro de la principal.

IF(LEN('Verificar RUT'!C4)=9;7;8)

Aquí verificamos la longitud de la celda donde se introduce el RUT. Si la longitud es igual a 9, se aplicará el número 7 en la fórmula principal; de lo contrario, se aplicará el 8.

Con base en lo explicado anteriormente, podemos observar que la fórmula principal se encarga de extraer X dígitos de izquierda a derecha. Según la longitud determinada por la fórmula interna, se obtendrán 7 u 8 dígitos de izquierda a derecha.

Como ejemplo, si ingreso el RUT 1234567-4, la fórmula proporcionará como resultado los dígitos 1234567.

Una vez obtenido el RUT sin el Dígito Verificador, es necesario ajustarlo a 8 dígitos para aplicar una fórmula estándar a los RUT de 7 y 8 dígitos. Para lograr esto, añadiremos un cero de la siguiente manera.

=IF(LEN(C2)=8;C2;CONCATENATE(0;C2))

Con las 2 fórmulas agregadas, ya deberíamos ver el siguiente resultado al ejemplo dado:

Ahora contamos con un RUT con el que podemos trabajar. A continuación, aplicaremos la fórmula oficial del Servicio de Impuestos Internos (SII), la cual podemos obtener en ESTE ENLACE.

Usando la fórmula de SII

Procederé a desglosar cada dígito del RUT con el fin de aplicar los cálculos según la fórmula establecida por el Servicio de Impuestos Internos (SII), de la siguiente manera.

=MID($C$3;8;1)

Extraeremos de la celda C3 (que contiene el RUT SIN DV en la última imagen) un dígito desde la posición 8, y repetiremos el proceso para los demás dígitos, cambiando sólo el número de posición de 8 a 7, 6, 5, 4, 3, 2 y 1.

Ahora que los dígitos del RUT están separados y dispuestos en orden inverso, procederemos a aplicar los cálculos utilizando la serie numérica 2, 3, 4, 5, 6 y 7.

=B5*2

En este ejemplo el cálculo sería: 7*2=14, 6*3=18, etc. Al llegar a 7 se comienza nuevamente con 2.

Ahora, la suma de los resultados nos arrojará 106. Pueden utilizar la función de autosuma para facilitar este proceso. Todo este proceso se debería ver de la siguiente forma:

El siguiente paso es dividir por 11 (módulo 11, según la aplicación del SII), lo que generará un resultado, posiblemente, con decimales.

Para evitar los decimales, aplicaremos la fórmula utilizando la función de entero de la siguiente manera.

=INT(C13/11)

Luego, aplicamos la fórmula de TOTAL – (11 * módulo 11), lo que nos proporcionará un dígito. Este cálculo se realizará con la siguiente fórmula.

=C13-(11*C15)

Ahora a 11 le restaremos el número que obtuvimos antes y nos dará como resultado el dígito verificador. La fórmula a continuación reemplazará el resultado si obtenemos 10 a K y si obtenemos 11 a 0.

=IF(INT(11-C16)=10;"K";IF(INT(11-C16)=11;"0";INT(11-C16)))
Validar RUT en Spreadsheet

En la imagen anterior, además de calcular el dígito verificador real del RUT, aparece el DV ingresado en la hoja verificar RUT. Esto lo conseguimos de la siguiente forma.

=INT(RIGHT('Verificar RUT'!C4;1))

Con estos pasos, obtenemos el primer dígito de derecha a izquierda. La última tarea será verificar si la persona ingresó un RUT con o sin Dígito Verificador. Para ello, empleamos la siguiente fórmula.

=IFERROR(if(FIND("-";'Verificar RUT'!C4; 1)>0;"CON DV");"SIN DV")

La función evalúa si la celda «Verificar RUT’!C4» contiene el signo «-«, y en caso afirmativo, si la posición del guion en el RUT es mayor a 0, el resultado será «CON DV». Si no se encuentra el guion, el resultado será el texto «SIN DV».

A continuación, la hoja de cálculos completa.

Validar RUT en Spreadsheet

Mostrando resultados

Ahora regresamos a la hoja «Verificar RUT» y añadimos una celda de resultado con el siguiente código.

=IF(Calculos!C21="SIN DV";CONCATENATE("DV = ";Calculos!C18);IF(Calculos!C19=Calculos!C18;"RUT VALIDO";"RUT INVALIDO"))

La explicación es la siguiente: si la celda «Calculos!C21» contiene la frase «SIN DV», entonces concatenará o unirá el texto «DV =» con el resultado de la celda «Calculos!C18». Si no contiene ese texto, realizará la siguiente comprobación: si la celda «Calculos!C19» (que contiene el DV ingresado en «Ingrese su RUT») es igual a la celda «Calculos!C18» (dígito verificador real), mostrará un mensaje de «RUT VÁLIDO»; de lo contrario, mostrará «RUT INVÁLIDO».

A continuación un ejemplo con DV y otro sin DV.

Validar RUT en Spreadsheet

Conclusión de validar RUT en Spreadsheet

En resumen, a lo largo de este proceso, hemos explorado cómo validar y verificar un RUT utilizando fórmulas y cálculos en una hoja de cálculo de Google. Desde la extracción del RUT sin Dígito Verificador hasta la aplicación de la fórmula del SII, hemos seguido pasos detallados para obtener un resultado preciso. La inclusión de verificaciones adicionales, como la presencia del guión y la comparación con el Dígito Verificador ingresado, nos permite determinar la validez del RUT ingresado. Este enfoque proporciona una herramienta práctica para aquellos que buscan validar RUTs de manera eficiente y precisa en un entorno de hoja de cálculo colaborativo.

¡Apoya mi página para que pueda seguir publicando más contenido interesante!
Tu donación es crucial para mantenerla activa y continuar compartiendo artículos de calidad.
¡Gracias por tu apoyo continuo!
Paypal

Comparte en redes
Sobre el administrador

Soy un ingeniero en conectividad y redes amante de la música y todo tipo de tecnologías.

Entradas similares
0 0 votes
Article Rating
Subscribe
Notify of
guest
0 Comments
Inline Feedbacks
View all comments