El tiempo con vbs


Con el siguiente código podemos ver el tiempo con vbs. A continuación intentaré explicar las partes más importantes del código el cual muestra el clima, la temperatura actual y otros datos.

Código vbs

Variable para la web del tiempo y otros. Deben cambiar CIXX0026 por el código de su ciudad.

Dim WeatherRSS
WeatherRSS = "http://xml.weather.com/weather/local/CIXX0026?cc=*&unit=m&dayf=7&locale=es_US"

Dim WinHttpReq, XMLData, objXML, weatherCity, weatherCondition, currTemp, highTemp, lowTemp, weather
Dim Response, Talker

Se abre el enlace de la página del tiempo para obtener los datos

Set WinHttpReq = CreateObject("WinHttp.WinHttpRequest.5.1")

WinHttpReq.Open "GET", WeatherRSS, False
WinHttpReq.Send

Si se obtiene el código 200 (conexión exitosa) comenzará a obtener ciertos datos

If (WinHttpReq.Status = 200) Then
   XMLData = WinHttpReq.ResponseText
   Set objXML = CreateObject("Microsoft.XMLDOM")
   objXML.async = "False"
   objXML.loadXML(XMLData)
   wht = objXML.getElementsByTagName("t").item(0).text
   tmp = objXML.getElementsByTagName("tmp").item(0).text
   flik = objXML.getElementsByTagName("flik").item(0).text
   hmd = objXML.getElementsByTagName("hmid").item(0).text
   hi = objXML.getElementsByTagName("hi").item(0).text
   low = objXML.getElementsByTagName("low").item(0).text

Se crea variable concatenando los resultados anteriores.

weather = "Clima: " + wht + vbCrLf + "Temperatura actual: " + tmp + "°" + vbCrLf + "Temperatura minima: " + low + "°" + vbCrLf + "Temperatura maxima: " + hi + "°" + vbCrLf + "Sensacion termica: " + flik + "°" + vbCrLf + "Humedad: " + hmd + "%"

Si no hay conexión exitosa, la variable mostrará el siguiente mensaje

else
   weather = "Lo siento, no es posible ver el pronostico para hoy"
end if

Se muestra el mensaje en una caja de mensaje con estos 3 parametros (el mensaje en si, la opción de mostrar un botón de aceptar(0), el titulo).

msgbox weather,0,"El tiempo en Valparaiso"

El resultado sería como muestra la siguiente imagen.

Este script sirve como ejemplo para obtener información de páginas xml y para incluirlo en los macros de speech macros.

Puedes descargar el script desde ESTE ENLACE.

Si tienes dudas sobre este script, como obtener tu código de ciudad u otro, no dudes en contactarme a través de los comentarios o al correo.

Saludos.